Crear una regla en Excel

A los programadores de Office de la Microsoft, nunca les patinó por el cerebro crear una regla en Excel que ayudara a los usuarios a simplicarse las tareas de impresión en facturas, notas de crédito, recibos, etc. quizá porque siempre se concentraron en otras características que consideraron más importantes que en una simple regla inútil, pero que tan inútil hubiera sido tener una regla en las versiones anteriores a Microsoft Office System 2007?

Ya se que podrían decir que hay programas que permiten medir longitudes en el monitor "supuestamente" en centimetros, como por ejemplo un programa llamado Screen Caliper, el JS Ruler, o el Screen Ruler, pero a la hora de empezar a tomar medidas para imprimir una hoja de cálculo de Excel adaptado a las dimensiones de una factura o documento en blanco para llenar, las medidas han fallado, no asi para medidas de archivos de imágenes que es específicamente para lo que se han hecho.

Personalmente, siempre busqué en la web "Googleando" (usando el buscador de Google) por todos lados, sin obtener frutos para resolver mi inquietud, hasta que un buen día hallé un buen código de programación que hacia lo que andaba buscando. Mi búsqueda había sido exitosa.

Abrí Excel y me dispuse a crear un módulo de Visual Basic vacío, como se hace eso? sencillo abres un libro nuevo y ve a al menú "Herramientas > Macros > Editor de Visual Basic". Entrarás al editor de Visual Basic correspondiente al libro que recien has abierto, de ahi ve al menú "Insertar" y seleccionas "Módulo" y en el area de edición tienes que pegar todo el código que aparece abajo de estas dos imágenes:

En la siguiente imágen está la ventana de Visual Basic en la cual debes seleccionar el libro (panel de la izquierda) en el cual estás trabajando y luego ir al menú insertar, seleccionando Módulo.

Pegar el siguiente código en la ventana que se abrirá:

Si ves que el texto de este código aparece como cortado solo usa la barra de desplazamiento al final para ver el resto.

Sub MakeRuler_inch()

'Definir el tamaño de la nueva regla.

Const Ruler_Width As Double = 6 'Width 6 inch
Const Ruler_Height As Double = 5 'Height 5 inch

'El tamaño de configuración en la pantalla y el tamaño actual en el impresor.

Const Screen_Width As Double = 6
Const Screen_Height As Double = 5
Const Printer_Width As Double = 6
Const Printer_Height As Double = 5

Dim i As Long
Dim l As Double
Dim x As Long
Dim y As Long
Dim ws As Worksheet
Dim a(0 To 15) As Double
Dim x2 As Double
Dim y2 As Double

x = Ruler_Width * 16
y = Ruler_Height * 16

a(0) = 3.6: a(1) = 1: a(2) = 2: a(3) = 1: a(4) = 2: a(5) = 1: a(6) = 2: a(7) = 1
a(8) = 3: a(9) = 1: a(10) = 2: a(11) = 1: a(12) = 2: a(13) = 1: a(14) = 2: a(15) = 1

Application.ScreenUpdating = False

Set ws = ActiveSheet
Worksheets.Add
ActiveSheet.Move
ActiveSheet.Lines.Add 0, 0, 3 * x, 0
For i = 1 To x
l = a(i Mod 16)
ActiveSheet.Lines.Add 3 * i, 0, 3 * i, 3 * l
Next

ActiveSheet.Lines.Add 0, 0, 0, 3 * y
For i = 1 To y
l = a(i Mod 16)
ActiveSheet.Lines.Add 0, 3 * i, 3 * l, 3 * i
Next

ActiveSheet.Lines.Border.ColorIndex = 55
For i = 16 To x - 1 Step 16
With ActiveSheet.TextBoxes.Add(3 * i - 9, 3 * 3.6, 18, 12)
.Text = Format(i \ 16, "!@@")
End With

Next
For i = 16 To y - 1 Step 16

With ActiveSheet.TextBoxes.Add(3 * 3.6, 3 * i - 9, 12, 18)
.Orientation = xlDownward
.Text = Format(i \ 16, "!@@")
End With
Next
With ActiveSheet.TextBoxes
.Font.Size = 9
.Font.ColorIndex = 55
.HorizontalAlignment = xlCenter
.VerticalAlignment = xlCenter
.Border.ColorIndex = xlNone
.Interior.ColorIndex = xlNone
End With

With ActiveSheet.DrawingObjects.Group

.Placement = xlFreeFloating
.Width = Application.InchesToPoints(x / 16)
.Height = Application.InchesToPoints(y / 16)
.CopyPicture xlScreen, xlPicture
ActiveSheet.Paste
x2 = (Selection.Width - .Width) / 3
y2 = (Selection.Height - .Height) / 3
Selection.Delete
.CopyPicture xlPrinter, xlPicture
ActiveSheet.Paste
.Width = .Width * .Width / (Selection.Width - x2 * 2) * Screen_Width / Printer_Width
.Height = .Height * .Height / (Selection.Height - y2 * 2) * Screen_Height / Printer_Height

Selection.Delete

If Val(Application.Version) >= 9 Then
.Copy
ActiveSheet.PasteSpecial 'Format:="Picture (PNG)"
With Selection.ShapeRange.PictureFormat

.CropLeft = x2
.CropTop = y2
.CropRight = x2
.CropBottom = y2

End With

Selection.Copy
ws.Activate
ws.PasteSpecial 'Format:="Picture (PNG)"
Selection.Placement = xlFreeFloating
.Parent.Parent.Close False
End If

End With

Application.ScreenUpdating = True
End Sub

'Regla para  Excel(Centimetros)

Sub MakeRuler_cm()

'Definir el tamaño de una nueva regla.

Const Ruler_Width As Double = 21 'Width 16 cm
Const Ruler_Height As Double = 28 'Height 14 cm

'The setting size on the screen and the actual size on the printer.

Const Screen_Width As Double = 21
Const Screen_Height As Double = 28
Const Printer_Width As Double = 21
Const Printer_Height As Double = 28

Dim i As Long
Dim l As Long
Dim x As Long
Dim y As Long
Dim ws As Worksheet
Dim x2 As Double
Dim y2 As Double

x = Ruler_Width * 10
y = Ruler_Height * 10

Application.ScreenUpdating = False

Set ws = ActiveSheet
Worksheets.Add
ActiveSheet.Move
ActiveSheet.Lines.Add 0, 0, 3 * x, 0
For i = 1 To x
If i Mod 10 = 0 Then l = 5 Else: If i Mod 5 = 0 Then l = 4 Else l = 3
ActiveSheet.Lines.Add 3 * i, 0, 3 * i, 3 * l
Next

ActiveSheet.Lines.Add 0, 0, 0, 3 * y
For i = 1 To y
If i Mod 10 = 0 Then l = 5 Else: If i Mod 5 = 0 Then l = 4 Else l = 3
ActiveSheet.Lines.Add 0, 3 * i, 3 * l, 3 * i
Next

ActiveSheet.Lines.Border.ColorIndex = 55
For i = 10 To x - 1 Step 10
With ActiveSheet.TextBoxes.Add(3 * i - 9, 3 * 5, 18, 12)
.Text = Format(i \ 10, "!@@")
End With

Next

For i = 10 To y - 1 Step 10

With ActiveSheet.TextBoxes.Add(3 * 5, 3 * i - 9, 12, 18)
.Orientation = xlDownward
.Text = Format(i \ 10, "!@@")
End With

Next

With ActiveSheet.TextBoxes
.Font.Size = 9
.Font.ColorIndex = 55
.HorizontalAlignment = xlCenter
.VerticalAlignment = xlCenter
.Border.ColorIndex = xlNone
.Interior.ColorIndex = xlNone
End With

With ActiveSheet.DrawingObjects.Group
.Placement = xlFreeFloating
.Width = Application.CentimetersToPoints(x / 10)
.Height = Application.CentimetersToPoints(y / 10)
.CopyPicture xlScreen, xlPicture
ActiveSheet.Paste
x2 = (Selection.Width - .Width) / 3
y2 = (Selection.Height - .Height) / 3
Selection.Delete

.CopyPicture xlPrinter, xlPicture

ActiveSheet.Paste
.Width = .Width * .Width / (Selection.Width - x2 * 2) * Screen_Width / Printer_Width
.Height = .Height * .Height / (Selection.Height - y2 * 2) * Screen_Height / Printer_Height

Selection.Delete

If Val(Application.Version) >= 9 Then
.Copy
ActiveSheet.PasteSpecial 'Format:="Picture (PNG)"

With Selection.ShapeRange.PictureFormat
.CropLeft = x2
.CropTop = y2
.CropRight = x2
.CropBottom = y2
End With

Selection.Copy

ws.Activate
ws.PasteSpecial 'Format:="Picture (PNG)"
Selection.Placement = xlFreeFloating
.Parent.Parent.Close False
End If

End With

Application.ScreenUpdating = True

End Sub

Luego que hayamos guardado, cierra el editor de Visual Basic (si no has guardado el libro hasta este momento, se abrirá la ventana de Guardar) y ve al libro en el que estamos trabajando y nuevamente ve a "Herramientas > Macro > Macros... el cual te mostrará la siguiente ventana:

Como podrás ver, ahi tendremos dos valores a escojer: MakeRuler_cm y MakeRuler_inch el cual nos indica que podemos crear la regla en Centímetros o en Pulgadas (inch viene de la palabra inglesa inches que significa pulgadas). Al final, para mostrar el resultado veremos algo parecido a esto:

Ahora quiero aclarar lo siguiente antes de que empiecen a hablar o hacer preguntas al respecto: lo que Excel genera al momento de ejecutar el Método que crea la regla, es una imagen PNG transparente pero con las medidas exactas con relación a una regla real. La imagen permanece encima de todas las celdas lo cual se vuelve en cierta manera util o fastidioso, pero que a la vez nos ayuda a que podamos arrastrar los bordes de las columnas y filas de manera que podamos ubicarlas a X distancia según la medida que tengamos de por ejemplo, una factura.

La verdad es que a una regla de este tipo se le puede dar todo tipo de usos según el grado de imaginación y creatividad que cada uno tenga al momento de trabajar en Excel. Yo, por ejemplo, la he usado varias veces para imprimir grandes cantidades de datos en facturas de todo tipo en la oficina de mi trabajo, y me he ahorrado mucho tiempo y trabajo, y de paso que ha sido de mucha utilidad para otros de mis compañeros. He publicado esto con el afán de que todos puedan hacer lo mismo, creando una regla que nunca puso Microsoft en Excel, sino hasta Excel 2007 la cual ya trae una incorporada. Si no quieres usar Office Excel 2007 sino que versiones previas, entonces esta es tu regla ideal.

Si ha sido de utilidad este articulo, te agradeceré un gentil comentario de tu parte.